vim 文字编辑器是 vi 文字编辑器的强化版本,两者都是运行在文字界面(CLI)上。vim 支持多次复原、多窗格、代码语法高亮和鼠标控制等多种功能,经常在 Linux 和 macOS 操作系统上被用来查看与编写代码,尤其是透过 SSH 连接来操作系统的时候更为常用。由于 vim 是如此常用的文字编辑器,且就算在别台电脑上都有可能会使用 SSH 连回自己的主机使用 vim 来编辑文字文件,以至于替 vim 设计出一个属于自己的编辑环境是非常有利于工作效率的。但究竟要怎么设计出自己的 vim 编辑环境呢?又能做到怎么样的效果呢?本篇文章将会透过 .vimrc 文件来一步步打造属于个人的 vim 环境。
首先来看看没设置 .vimrc 文件时,打开 Java 源代码文件的结果。
从上图可以看到显示出来虽然有代码高亮和成对括号标示,但没有显示行号和光标行列提示,仅有显示光标座标,这样并不利于代码的阅读。然而,加入自己的 .vimrc 文件后,就可以显示出如下图的效果,使 vim 的文字配色更能符合自己的喜好,也能显示行号和光标行列提示(光标十字瞄准线),让程序阅读更加迅速!
使用 .vimrc 文件进行 vim 环境设置
vim 文字编辑器有自己的命令行模式,用户可以在 vim 内下达一些指令来完成特定的动作,像是设置环境变量、快速键、配色等等,都可以透过 vim 文字编辑器的命令行模式来完成。vim 在打开的时候会先去读取用户家目录下的 .vimrc 文件(~/.vimrc),并且自动运行这个文件中的所有指令。也就是说,.vimrc 文件可以让用户自行决定其 vim 文字编辑器应该要透过环境变量打开哪些特定的功能(如行号显示),也可以让用户加入自己的快速键来完成指定的工作,最重要、同时也是最常用的就是能事先指定配色了!
让 vim 能支持 256 色
vim 的 t_Co 环境变量决定了 vim 支持的颜色数量,如果要让 vim 显示出来的效果好看一些,建议将这个环境变量设为 256,也就是 vim 最大能支持的 256 色。
在 .vimrc 文件中添加以下指令:
透过颜色方案来做好全套配色
vim 有颜色方案(colorscheme)的功能,可以让用户使用 colorscheme 或是 colo 指令来设置 vim 的配色主题。vim 通常会内置几个颜色方案,存在 /usr/share/vim/vimNN/colors(NN 是 vim 的版本号码)目录中,扩展名为 .vim。以下挑几个内置的颜色方案来给大家看看:
default
koehler
darkblue
desert
shine
ron
torte
笔者觉得内置的几个颜色方案中,torte 是看得最顺眼的一个。如果要将 torte 作为 vim 的初始颜色方案,可以将以下指令写入 .vimrc 文件中:
或是缩写成:
除了官方内置的颜色方案能使用之外,网络上也有很多地方有提供他人制作的 vim 颜色方案,只要将该颜色方案的 .vim 文件放置于 ~/.vim/colors/ 目录中,即可使用 colorscheme 或是 colo 指令来套用。例如从 vim 官方网站找到的 lucid.vim 就可以放置在那个目录中,并使用以下指令来套用:
显示光标所在的列
若要显示光标所在的「列(row)」,也就是标示出光标所在的水平方向,可以使用以下指令来打开:
如果要关闭,可以使用以下指令来关闭:
如果觉得预设标示列的方式只是用底线,感觉很丑而且又会挡到真正的底线字符的话,可以使用 highlight 或是 hi 指令来调整,如下:
以上指令中,cterm 用来调整文字上的变化:none 表示维持不变;underline 表示增加底线;bold 可以将文字加粗;reverse 会将颜色反白。
ctermbg 和 ctermfg 分别用来调整背景色和前景色,颜色可以使用 vim 的 256 色编号(如下图表),也可以使用以下的 16 色英文单字:Black、DarkBlue、DarkGreen、DarkCyan、DarkRed、DarkMagenta、Brown (DarkYellow)、LightGray(LightGrey、Gray、Grey)、DarkGray (DarkGrey)、Blue (LightBlue)、Green (LightGreen)、Cyan (LightCyan)、Red (LightRed)、Magenta (LightMagenta)、Yellow (LightYellow)、White。
调整之后的效果如下:
注意 highlight 或是 hi 指令应写在 colorscheme 之后。
显示光标所在的行
若要显示光标所在的「行(column)」,也就是标示出光标所在的垂直方向,可以使用以下指令来打开:
如果要关闭,可以使用以下指令来关闭:
如果觉得预设标示行的方式不好看的话,同样也可以使用 highlight 或是 hi 指令来调整,如下:
调整之后的效果如下:
注意 highlight 或是 hi 指令应写在 colorscheme 之后。
打开/关闭 vim 的代码语法高亮支持
使用以下指令可以打开 vim 的代码语法高亮功能:
使用以下指令可以关闭 vim 的代码语法高亮功能:
注意 syntax 指令应写在 highlight 之前。
打开/关闭 vim 的 vi 兼容模式
使用以下指令可以打开 vim 的 vi 兼容模式:
打开了之后,会有许多属于 vim 的功能无法被使用。一般都会使用以下指令来关闭 vim 的 vi 兼容模式:
建议在一开始就先运行这行指令。
打开/关闭 vim 的行号显示
使用以下指令可以打开 vim 的行号显示:
调整之后的效果如下:
使用以下指令可以关闭 vim 的行号显示:
打开/关闭 vim 的光标座标显示
使用以下指令可以打开 vim 的右下角光标座标显示:
使用以下指令可以关闭 vim 的右下角光标座标显示:
打开/关闭 vim 的忽略大小写搜索
使用以下指令可以打开 vim 的忽略大小写搜索:
在 ignorecase 状态下,若搜索 the,则 THE、tHE、The……等子字符串都算是符合搜索条件。
使用以下指令可以关闭 vim 的忽略大小写搜索:
如果要在 noignorecase 的状态下忽略大小写进行搜索的话,要在搜索样本中加上 \c。
打开/关闭 vim 的智能大小写搜索
使用以下指令可以打开 vim 的智能大小写搜索:
如果 smartcase 和 ignorecase 都被打开,此时搜索 the,则 THE、tHE、The……等子字符串都算是符合搜索条件;但搜索 The,则只有 The 符合搜索条件。
使用以下指令可以关闭 vim 的智能大小写搜索:
打开/关闭 vim 的搜索结果高亮提示
使用以下指令可以打开 vim 的搜索结果高亮提示:
调整之后会将搜索到的所有结果进行高亮显示,效果如下:
使用以下指令可以关闭 vim 的搜索结果高亮提示:
如果觉得 vim 预设的高亮提示不好看的话,可以使用 highlight 或是 hi 指令来调整,如下:
调整之后可以将搜索结果反白显示,效果如下:
注意 highlight 或是 hi 指令应写在 colorscheme 之后。
打开/关闭 vim 的加强版搜索功能
使用以下指令可以打开 vim 的加强版搜索功能:
打开 incsearch 之后,在输入搜索样本的期间就会开始进行搜索了,不用等到样本全部输入完成。如果有打开 hlsearch,则会在样本确定输入完成后(按下 Enter)才会把所有符合样本的结果高亮显示。
使用以下指令可以关闭 vim 的加强版搜索功能:
打开/关闭 vim 的自动缩进功能
vim 的自动缩进有 autoindent、smartindent 和 cindent 三种。autoindent 是最基本的缩进方式,会在创建出新的一行的同时,自动对齐上一行的缩进。smartindent 则是会在 autoindent 的基础上,针对 {(左大括号)后所产生的新行,再多往内缩进一次,且若新行的开头是 }(右大括号),则会取消往内缩多排一次的动作。而 cindent 则是会在 smartindent 的基础上,加入简单的 C/C++、Java 等程序语法结构的判断,如果 { 是发生在注解之内,就不会进行缩进,并且也不是根据新行的上一行来决定新行的缩进,而是会根据新行所在的程序区块(block)来决定,另外也会根据其他符号进行缩进。
使用以下指令可以打开 vim 的 cindent 自动缩进功能:
使用以下指令可以关闭 vim 的 cindent 自动缩进功能:
vim 的 TAB 和空格处理
使用以下指令可以打开 vim 的 TAB 扩展功能:
将 TAB 扩展功能打开之后,在 vim 插入的 TAB 字符就可以被扩展成一个或是多个空格(space)。如果要插入原本的 TAB 字符,可以先按下 Ctrl + v,再按下 Tab 键。
使用以下指令可以关闭 vim 的 TAB 扩展功能:
如果要设置 vim 将一个 TAB 扩展成多个空格的空格数量,可以设置 tabstop 和 softtabstop 这两个环境变量。例如要将一个 TAB 扩展成四个空格的话,可以使用以下指令将 tabstop 和 softtabstop 设为 4:
set softtabstop=4
tabstop 和 softtabstop 的功能略有差异,简单来说,tabstop 是 vim 对于 TAB 字符本身的宽度定义,如果有打开 TAB 扩展功能,则这个宽度就等于是空格字符的数量。而 softtabstop 是 vim 对于「虚拟 TAB」字符的宽度定义,这个「虚拟 TAB」字符表示的宽度会尽量以 TAB 字符来做填满,没有填满的部份会以空格字符来取代。举例来说,如果将 tabstop 设为 3,softtabstop 设为 8,在使用键盘按键插入 TAB 字符时(实际上会是一个「虚拟 TAB」字符),会产生两个 TAB 字符(共六个字符的宽度)和两个空格字符来补足八个字符的宽度。若有打开 TAB 扩展功能,两个 TAB 字符会被扩展成六个空格字符,也就会变成是八个空格字符。
如果要设置原本自动缩进产生的字符宽度,则需要使用 shiftwidth 这个环境变量来决定其 TAB 字符和用来扩展的空格字符所组合而成的字符宽度。可以使用以下指令将 shiftwidth 设为 4:
如果将 tabstop 设为 3,shiftwidth 设为 4,自动缩进的时候会产生一个 TAB 字符(三个字符的宽度)和一个空格字符来补足四个字符的宽度。若有打开 TAB 扩展功能,一个 TAB 字符会被扩展成三个空格字符,也就会变成是四个空格字符。
另外,虽然 vim 有自动缩进功能,但有时候我们还是会手动在一行的最前面,使用键盘的 TAB 按键来进行缩进。前面有提到过,键盘 TAB 按键的宽度是基于 softtabstop 变量所形成的「虚拟 TAB」字符,而不是自动缩进时所使用的 shiftwidth 环境变量。如果要在行首插入缩进字符时,也能使用 shiftwidth 环境变量所定义的宽度,那么可以打开 vim 的智能 TAB 功能。
使用以下指令可以打开 vim 的智能 TAB 功能:
使用以下指令可以关闭 vim 的智能 TAB 功能:
打开/关闭 vim 的确认功能
使用以下指令可以打开 vim 的确认功能:
打开 vim 的确认功能之后,遇到需要进行确认的动作时(例如要不保存文档内容改变而关闭 vim 时),vim 会出现确认消息,要求用户回答,而不是直接阻挡用户进行该项动作。
使用以下指令可以关闭 vim 的确认功能:
设置 backspace 键的功能
vim 可以透过 backspace 环境变量,设置其在编辑模式下,键盘上 backspace 键的功能。可以使用以下指令来打开 backspace 键的所有功能:
或是:
indent 表示允许使用 backspace 键来删除缩进;eol 表示允许使用 backspace 来删除换行字符,使其可以退回至上一行;start 表示允许使用 Ctrl + w 和 Ctrl + u 快速键来删除独立词语和同类字符(缩进、非缩进字符)。
设置 vim 记录已运行指令的数量上限
vim 可以透过 history 环境变量,设置其所能记录的已运行指令之数量上限。可以将数量上限设多一点,以利查找。若要让 vim 保存 500 笔指令,可以使用以下指令:
打开/关闭 vim 的状态栏
vim 可以透过 laststatus 环境变量,设置其状态栏的显示方式。
使用以下指令可以打开 vim 的状态栏:
调整之后的效果如下:
使用以下指令可以关闭 vim 的状态栏:
修改 vim 的状态栏
vim 可以透过 statusline 环境变量,设置其状态栏的文字格式。其中,%t 代表文件名称;%F 代表文件路径;%y 代表文件类型;%= 代表左右分隔;%c 代表目前光标所在的行号;%l 代表目前光标所在的列号;%L 代表总列数;%p 代表目前浏览位置的进度百分比。
在 .vimrc 文件中添加以下指令配置:
set statusline=[%{expand('%:p')}][%{strlen(&fenc)?&fenc:&enc},\ %{&ff},\ %{strlen(&filetype)?&filetype:'plain'}]%{FileSize()}%{IsBinary()}%=%c,%l/%L\ [%3p%%]
function IsBinary()
if (&binary == 0)
return ""
else
return "[Binary]"
endif
endfunction
function FileSize()
let bytes = getfsize(expand("%:p"))
if bytes <= 0
return "[Empty]"
endif
if bytes < 1024
return "[" . bytes . "B]"
elseif bytes < 1048576
return "[" . (bytes / 1024) . "KB]"
else
return "[" . (bytes / 1048576) . "MB]"
endif
endfunction
调整之后的效果如下:
还能显示文件大小呢!
若要修改配色,可以在文字格式加上 %*(切换回预设配色)和 %#配色名称#,并配合 highlight 或是 hi 指令来调整。可以将以上指令配置修改如下:
set statusline=%#filepath#[%{expand('%:p')}]%#filetype#[%{strlen(&fenc)?&fenc:&enc},\ %{&ff},\ %{strlen(&filetype)?&filetype:'plain'}]%#filesize#%{FileSize()}%{IsBinary()}%=%#position#%c,%l/%L\ [%3p%%]
hi filepath cterm=none ctermbg=238 ctermfg=40
hi filetype cterm=none ctermbg=238 ctermfg=45
hi filesize cterm=none ctermbg=238 ctermfg=225
hi position cterm=none ctermbg=238 ctermfg=228
调整之后的效果如下:
注意 highlight 或是 hi 指令应写在 colorscheme 之后。
打开/关闭 vim 的指令暂存提示
使用以下指令可以打开 vim 的指令暂存提示:
打开指令暂存提示之后,vim 就可以在右下角显示用户之前输入的指令,如下图:
如此一来就可以有效提醒用户目前指令输入到哪里了。
使用以下指令可以关闭 vim 的指令暂存提示:
打开/关闭 vim 的模式提示
使用以下指令可以打开 vim 的模式提示:
打开模式提示之后,vim 才可以在底部显示目前使用的操作模式是一般、插入、取代还是选取模式。
使用以下指令可以关闭 vim 的模式提示:
打开/关闭 vim 的自动换行
使用以下指令可以打开 vim 的自动换行:
打开自动换行之后,若一行的文字长度超过 vim 所能显示的范围,就会换行显示。建议与显示行号功能一起使用。
使用以下指令可以关闭 vim 的自动换行:
打开/关闭 vim 的自动存盘
使用以下指令可以打开 vim 的自动存盘:
打开自动存盘之后,在运行 :next、:make、:! 等会切换到其它文件或是运行外部指令的命令前,vim 就会自动将修改过的文件存盘。要注意的是,vim 编辑器失去焦点时并不会自动存盘。
使用以下指令可以关闭 vim 的自动存盘:
打开/关闭 vim 的鼠标控制功能
vim 可以透过 mouse 环境变量,设置其鼠标在哪些模式下可以被用来操作编辑器。n 为一般模式;v 为视觉模式;i 为插入模式;c 为命令行模式;a 为所有模式。
使用以下指令可以在所有模式下打开 vim 的鼠标控制功能:
打开鼠标控制功能之后,就可以使用鼠标来控制 vim 的光标了!
使用以下指令可以关闭 vim 的鼠标控制功能:
vim 的多国语系编码判断
在打开文字文件的时候,偶尔会因为解码时所用的字符编码方式(字符集)不符合正确的字符编码,而出现乱码的情形。如下图:
vim 可以透过 fileencodings 环境变量,设置其在打开文字档时要优先使用什么字符编码方式来打开。但前提是它在编译前要先设置好有支持 multi_byte 功能。可以在 .vimrc 文件中撰写以下判断式来判断 vim 有无支持 multi_byte 功能:
if has("multi_byte")
else
echoerr "If +multi_byte is not included, you should compile Vim with big features."
endif
我们可以依照自己经常接触的字符编码和它们个别涵盖的字符范围及严谨程度来排列出尝试解码的顺序,并设置给 fileencodings 环境变量保存。如下:
万国码「UTF」是涵盖率最高,同时也是最常用的字符编码,而且编码方式都很严谨。其中 UTF-8 又较 UTF-16 更严格一点,因此排在首位来尝试解码。由于笔者是正体中文用户,因此再来是以正体中文为主的 big5 和以简体中文为主的 gb2312,这两种编码方式相对不严谨,但会频繁遇到。接着是涵盖更多中文及其它字符的 gbk 与 gb18030 编码。中文尝试结束之后,再来尝试日文所使用的 euc-jp 和韩文使用的 euc-kr。最后使用最不严谨的 latin1 来垫底。
设置完 fileencodings 环境变量之后,就比较不会开到乱码文件了!
为了确保 vim 内部有办法使用所有的字符,也建议将 encoding 环境变量固定为 utf-8。指令如下:
这是为了避免 encoding 若是设为 big5,而读取了 big5 范围之外的字符,就算 fileencodings 有命中,并且可以成功解码,但在内部进行编码转换时还是会无法将该字符转成 big5 而发生问题。
如果用户的终端机并不是使用与 vim 所在的主机一样的文字编码,则需要修改 termencoding 环境变量,将其设置成属于自己终端环境的编码方式,若编码不合的话会有乱码的问题发生。
加入自订的快速键
vim 的 map、nmap、vmap、omap、map!、imap、cmap 指令可以在不同 vim 操作模式下创建快速键。其中,map 涵盖了一般模式和视觉模式;map! 涵盖了 map 没包含的模式;imap 只涵盖插入模式;cmap 只涵盖命令行模式。
map 指令家族的用法都一样,格式如下:
例如在 .vimrc 设置档加入:
即可在 vim 的一般模式和视觉模式下,按下快速键 Ctrl + t 来显示自动缩进的宽度。由于 vim 内置的快速键以及终端机软件内置的快速键已经有很多,所以要找到能够自订的快速键也不太容易,这是需要不断尝试的部份哦!
使用 Ctrl + n 来切换鼠标模式
当 vim 打开了鼠标模式之后,终端机原本需要使用鼠标进行的功能(如右键菜单)可能就会无法使用,因此笔者将这个功能做成快速键来切换。在 .vimrc 设置档加入以下片段,就能用 Ctrl + n 快速键来进行鼠标模式的切换了!
map <C-n> :call SwitchMouseMode()<CR>
map! <C-n> <Esc>:call SwitchMouseMode()<CR>
function SwitchMouseMode()
if (&mouse == "a")
let &mouse = ""
echo "Mouse is disabled."
else
let &mouse = "a"
echo "Mouse is enabled."
endif
endfunction
使用 Ctrl + b 来切换文字/二进制模式
在特殊的情况下,我们需要使用二进制模式来编辑文字文件,单纯地将字符写入至文件中,防止 vim 文字编辑器鸡婆地对其加入 EOL 字符(End of Line),而让文件莫名其妙多出了一个字节的数据。在 .vimrc 设置档加入以下片段,就能用 Ctrl + b 快速键来进行文字及二进制模式的切换了!
map <C-b> :call SwitchTextBinaryMode()<CR>
map! <C-b> <Esc>:call SwitchTextBinaryMode()<CR>
function SwitchTextBinaryMode()
if (&binary == 0)
set binary
set noeol
echo "Switch to binary mode."
else
set nobinary
set eol
echo "Switch to text mode."
endif
endfunction
使用 Ctrl + j 强制将目前打开的文档转成 UTF-8 编码
由于跨平台、国际化的问题,将文档使用最普遍的 UTF-8 编码来保存是最方便、保险的。在 .vimrc 设置档加入以下片段,就能用 Ctrl + j 快速键来对该文档进行 UTF-8 编码的强制转换!
map <C-j> :call ToUTF8()<CR>
map! <C-j> <Esc>:call ToUTF8()<CR>
function ToUTF8()
if (&fileencoding == "utf-8")
echo "It is already UTF-8."
else
let &fileencoding="utf-8"
echo "Convert to UTF-8."
endif
let &ff="unix"
endfunction
利用修改 fileencoding 环境变量的方式来转换文档的编码。顺便修改 ff 环境变量,使文档变成 unix 兼容的格式。
使用 Ctrl + t 将所有 TAB 字符转成空格字符
一个文档的缩进字符如果混杂着 TAB 字符和空格字符,有时会十分不便。在 .vimrc 设置档加入以下片段,就能用 Ctrl + t 快速键来将该文档中的 TAB 字符扩展成空格字符!
map <C-t> :call TabToSpaces()<CR>
map! <C-t> <Esc>:call TabToSpaces()<CR>
function TabToSpaces()
retab
echo "Convert tab to spaces."
endfunction
使用 retab 指令来转换 TAB 字符。
使用 Ctrl + l 来切换自动断行模式
在不同需求下,我们有时会需要自动断行功能,有时不需要自动断行功能。在 .vimrc 设置档加入以下片段,就能用 Ctrl + l 快速键来进行自动断行模式的切换了!
map <C-l> :call SwitchLineBreakingMode()<CR>
map! <C-l> <Esc>:call SwitchLineBreakingMode()<CR>
function SwitchLineBreakingMode()
if (&wrap == 0)
set wrap
echo "Switch to line breaking mode."
else
set nowrap
echo "Switch to one line mode."
endif
endfunction
使用 Ctrl + f 来切换完整/简单模式
笔者习惯使用鼠标来选取终端机内的文字进行快速键或是右键拷贝,再至指定位置使用快速键或是右键粘贴。如果 vim 有设置鼠标模式、显示行号且无自动断行的话,拷贝文字时将会遇到一些困难。再来是如果 vim 有打开自动缩进功能的话,粘贴文字时,原先的排版也会乱掉。所以特别开了一个快速键来切换完整和简单模式,在简单模式下可以照原本的终端机使用习惯,在 vim 内进行选取和拷贝粘贴。
map <C-f> :call SwitchFullSimpleMode()<CR>
map! <C-f> <Esc>:call SwitchFullSimpleMode()<CR>
function SwitchFullSimpleMode()
if (&mouse == "a")
let &mouse = ""
set nocindent
set nonumber
set wrap
echo "Switch to simple mode.(nomouse, nonumber, nocindent, wrap)"
else
let &mouse = "a"
set cindent
set number
set nowrap
echo "Switch to full mode.(mouse, number, cindent, nowrap)"
endif
endfunction
完整的 .vimrc 文件
以上对于 vim 指令及 .vimrc 文件的介绍因为东西很杂很多,可能会让各位看得雾煞煞,因此笔者在文章最后发布已撰写完成的 .vimrc 文件。文件内容如下:
"################### Magic vimrc ###################
" ctrl+n Enable/disable mouse
" ctrl+b Switch to text/binary
" ctrl+j To utf-8 file
" ctrl+t Convert tab to spaces
" ctrl+l Toggle line breaking
" ctrl+f Switch to full/simple
"#######################################################
set nocompatible
"#######################################################
syntax enable
set number
set noruler
set ignorecase
set smartcase
set incsearch
set cindent
set expandtab
set tabstop=4
set softtabstop=4
set shiftwidth=4
set smarttab
set confirm
set backspace=indent,eol,start
set history=500
set showcmd
set showmode
set nowrap
set autowrite
set mouse=a
"#######################################################
" Color
set t_Co=256
colo torte
set cursorline
set cursorcolumn
set hlsearch
hi CursorLine cterm=none ctermbg=DarkMagenta ctermfg=White
hi CursorColumn cterm=none ctermbg=DarkMagenta ctermfg=White
hi Search cterm=reverse ctermbg=none ctermfg=none
"#######################################################
" statusline
set laststatus=2
set statusline=%#filepath#[%{expand('%:p')}]%#filetype#[%{strlen(&fenc)?&fenc:&enc},\ %{&ff},\ %{strlen(&filetype)?&filetype:'plain'}]%#filesize#%{FileSize()}%{IsBinary()}%=%#position#%c,%l/%L\ [%3p%%]
hi filepath cterm=none ctermbg=238 ctermfg=40
hi filetype cterm=none ctermbg=238 ctermfg=45
hi filesize cterm=none ctermbg=238 ctermfg=225
hi position cterm=none ctermbg=238 ctermfg=228
function IsBinary()
if (&binary == 0)
return ""
else
return "[Binary]"
endif
endfunction
function FileSize()
let bytes = getfsize(expand("%:p"))
if bytes <= 0
return "[Empty]"
endif
if bytes < 1024
return "[" . bytes . "B]"
elseif bytes < 1048576
return "[" . (bytes / 1024) . "KB]"
else
return "[" . (bytes / 1048576) . "MB]"
endif
endfunction
"#######################################################
" encode
if has("multi_byte")
set fileencodings=utf-8,utf-16,big5,gb2312,gbk,gb18030,euc-jp,euc-kr,latin1
else
echoerr "If +multi_byte is not included, you should compile Vim with big features."
endif
"#######################################################
" shortcut
" Toggle mouse
map <C-n> :call SwitchMouseMode()<CR>
map! <C-n> <Esc>:call SwitchMouseMode()<CR>
function SwitchMouseMode()
if (&mouse == "a")
let &mouse = ""
echo "Mouse is disabled."
else
let &mouse = "a"
echo "Mouse is enabled."
endif
endfunction
" Toggle text/binary
map <C-b> :call SwitchTextBinaryMode()<CR>
map! <C-b> <Esc>:call SwitchTextBinaryMode()<CR>
function SwitchTextBinaryMode()
if (&binary == 0)
set binary
set noeol
echo "Switch to binary mode."
else
set nobinary
set eol
echo "Switch to text mode."
endif
endfunction
" To utf-8 file
map <C-j> :call ToUTF8()<CR>
map! <C-j> <Esc>:call ToUTF8()<CR>
function ToUTF8()
if (&fileencoding == "utf-8")
echo "It is already UTF-8."
else
let &fileencoding="utf-8"
echo "Convert to UTF-8."
endif
let &ff="unix"
endfunction
" Convert tab to spaces
map <C-t> :call TabToSpaces()<CR>
map! <C-t> <Esc>:call TabToSpaces()<CR>
function TabToSpaces()
retab
echo "Convert tab to spaces."
endfunction
" Toggle line breaking
map <C-l> :call SwitchLineBreakingMode()<CR>
map! <C-l> <Esc>:call SwitchLineBreakingMode()<CR>
function SwitchLineBreakingMode()
if (&wrap == 0)
set wrap
echo "Switch to line breaking mode."
else
set nowrap
echo "Switch to one line mode."
endif
endfunction
" Switch to full/simple
map <C-f> :call SwitchFullSimpleMode()<CR>
map! <C-f> <Esc>:call SwitchFullSimpleMode()<CR>
function SwitchFullSimpleMode()
if (&mouse == "a")
let &mouse = ""
set nocindent
set nonumber
set wrap
echo "Switch to simple mode.(nomouse, nonumber, nocindent, wrap)"
else
let &mouse = "a"
set cindent
set number
set nowrap
echo "Switch to full mode.(mouse, number, cindent, nowrap)"
endif
endfunction



























