声音是由声波产生,声波的形状代表着声音的音色,声波的振幅代表着声音的大小,声波的频率代表着声音的高低。声波是形成声音最基本的物理现象,因此若要制造声音,就必须先制造「波(Wave)」。在 Csound 中,产生声波必须要靠 Function Table(波表)、GEN Routine 和 Oscillator(振荡器)来共同完成。

Function Table

由于数字化的限制,没办法产生出完全连续的数字波形,势必得把一个波形切成细小块来逼近,这个过程就称为「采样(Sampling)」。举例:若要产生一个由数值 0~1 线性成长的波形,若要数字化表示,可能就得表示成「0, 0.5, 1」(3 个样本点)、「0, 0.25, 0.5, 0.75, 1」(5 个样本点)。若是取 5 个样本点(Sample),若我们原先需要 0.3 这个值的话,采样后就会变成 0.25,造成波形的失真。因此,采样数愈多,愈能够还原出原本的波形,失真的状况也会更加轻微。一个周期的波有几个样本数量,就是波表的大小。要注意它和采样率(Sample Rate)不同,采样率是指每秒有几个样本数量,例如之后范例程序中的 sr = 44100。

下图是三角函数 sin 波,上下两个 sin 波的波表大小分别是 16 和 8192。可以明显看出,样本数量太少的波形,非常的不圆滑!

波表大小分别为 16 与 8192 的正弦波

Function Table 就是用来纪录一个波形在每个时间点上的值,就是用来保存采样结果的表格啦!在 Csound 中又称为「f Statement」,因为要定义一个 Function Table,就必须要用到 f Statement。格式如下:

f p1 p2 p3 p4 p5 ... PMAX
  • p1:表格的代号。
  • p2:波的起始时间。
  • p3:表格的大小,也就是一个周期的波有几个样本数量。数值必须为 2n 或是 2n+1。
  • p4:产生出波的规则(GEN Routine 的号码)。
  • p5... PMAX:GEN Routine 的参数。

GEN Routine

GEN Routine 全名应为 Generating Routine,就是产生波的规则,可以借由定义规则,来生成任意形状的波形。在 Csound 中,GEN Routine 有好几种,皆以数字代号来表示。例如代号 10 (GEN10),就是用来产生出 sin 或是 sin 的谐波组成的波形,因此除了基本的正弦波外还可以产生出方波、脉冲波、三角波。不同代号的 GEN,后面所接的参数差异颇大。

GEN10

产生出 sin 或是 sin 的谐波组成的波形。格式如下:

f p1 p2 p3 10 hw1 [hw2 ...]
  • hw:顺序为谐波次数(从 1 次谐波开始),数值决定谐波的振幅权重。

GEN5

产生出多个曲线线段组成的波形。格式如下:

f p1 p2 p3 5 a la [b lb [c lc [d ...] ]]
  • a,b,c,d...:波的值。
  • la,lb,lc...:从这波值变化到下个波值的长度,加总应小于或等于 p3。

GEN7

产生出多个直线线段组成的波形。格式如下:

f p1 p2 p3 7 a la [b lb [c lc [d ...] ]]
  • a,b,c,d...:波的值。
  • la,lb,lc...:从这波值变化到下个波值的长度,加总应小于或等于 p3。

GEN21

产生出乱数波表,用来产生杂讯。格式如下:

f p1 p2 p3 21 type level [arg1 [arg2]]
  • type:1~11,乱数的种类,常会使用 1 号。
  • level:振幅。
  • arg1:type 9,10 需要传入,type 6 可选择是否要传入。
  • arg2:type 9 需要传入。

GEN01

从音频文件中取 Sample,产生出波表。格式如下:

f p1 p2 p3 1 filcod skiptime format channel
  • filcod:文件号码(soundin.filcod)或路径。支持 WAV 和 OGG 文件。
  • skiptime:跳过时间,要从哪个时间点后开始采样。(单位:秒)
  • format:0~6,常用的数值是 0,4,5,6。0 是读入文件的格式 ,4 是 16 比特的短整数;5 是 32 比特的长整数;6 是 32 比特的浮点数。一般设 0 或 6 都可以正常使用。
  • channel:要读取的声道编号,0 为所有声道。

其他 GEN 的用法日后再慢慢补充。

Oscillator

Oscillator,可称为振荡器,可用来将 Function Table 振荡成真正的波,就是可以算出在某时间点下的波应该要为什么数值。Function Table 决定的是波的波形,而 Oscillator 所决定的是波的振幅和频率,若要产生出波,两者缺一不可。在 Csound 中,可用 oscil 来简单地振荡出波。oscil 的格式如下:

av oscil amp, cps, fn [, phs]
  • av:在目前时间点下,波的数值。
  • amp:波的振幅。
  • cps:波的频率(Cycles per second)。
  • fn:Function Table 的代号。
  • phs:波形的相位移。数值为 0~1,若一个波周期为 2π,那么数值 0.5 就是代表 π。如果不设置这项参数,默认值为 0。

常用波形的振荡方式

下面是一个正弦波的振荡范例程序,振幅为 0db、频率为 1、周期为 1 秒,一共振荡出两个全波(共 2 秒)。

<CsoundSynthesizer>
	<CsOptions>
	</CsOptions>
	
	<CsInstruments>
		sr = 44100   ;sample rate
		ksmps = 16   ;samples in a control period
		nchnls = 1   ;number of channels
		0dbfs = 100  ;value of 0db
		
		instr 1
			;p4=frequent
			;p3=duration		 							
			a1 oscil 100, p4, 1 ;oscillate f1
			out a1              ;output
		endin
	</CsInstruments>
	<CsScore>
		f1 0 16384 10 1
		t 0 60
		
		;ins	strt	dur	freq
		i1	0	2	1
		e
	</CsScore>
</CsoundSynthesizer>

正弦波

要振荡出正弦波,可用 GEN10,参数传入:

1

GEN10 产生的正弦波波形

正弦波试听

方波

要振荡出方波,可用 GEN10,参数传入:

1 0 0.33333 0 0.2 0 0.14286 0 0.11111 0 0.09091 0 0.07692 0 0.06667 0 0.05882 0 0.05263 0 0.04762 0 0.04348 0 0.04 0 0.03704 0 0.03448 0 0.03226 0 0.0303 0 0.02857 0 0.02703 0 0.02564 0 0.02439 0 0.02326 0 0.02222 0 0.02128 0 0.02041 0

GEN10 产生的方波波形

方波试听

锯齿波

要振荡出锯齿波,可用 GEN10,参数传入:

1 -0.5 0.33333 -0.25 0.2 -0.16667 0.14286 -0.125 0.11111 -0.1 0.09091 -0.08333 0.07692 -0.07143 0.06667 -0.0625 0.05882 -0.05556 0.05263 -0.05 0.04762 -0.04545 0.04348 -0.04167 0.04 -0.03846 0.03704 -0.03571 0.03448 -0.03333 0.03226 -0.03125 0.0303 -0.02941 0.02857 -0.02778 0.02703 -0.02632 0.02564 -0.025 0.02439 -0.02381 0.02326 -0.02273 0.02222 -0.02174 0.02128 -0.02083 0.02041 -0.02

GEN10 产生的锯齿波波形

锯齿波试听

三角波

要振荡出三角波,可用 GEN10,参数传入:

1 0 -0.11111 0 0.04 0 -0.02041 0 0.01235 0 -0.00826 0 0.00592 0 -0.00444 0 0.00346 0 -0.00277 0 0.00227 0 -0.00189 0 0.0016 0 -0.00137 0 0.00119 0 -0.00104 0 0.00092 0 -0.00082 0 0.00073 0 -0.00066 0 0.00059 0 -0.00054 0 0.00049 0 -0.00045 0 0.00042 0

GEN10 产生的三角波波形

三角波试听

脉冲波

要振荡出脉冲波,可用 GEN10,参数传入:

1 1 1 1 1 0.8 0.6 0.4 0.2 0

GEN10 产生的脉冲波波形

脉冲波试听

正脉冲方波

要振荡出正脉冲方波,可用 GEN7,参数传入:

1 4096 1 0 0 4096 0

GEN7 产生的正脉冲方波波形

正脉冲方波试听

其他波形因为牵扯到组合复杂波形的问题,日后有了对应文章再慢慢补充。