FM(频率调制,Frequency Modulation)除了可以用来产生抖音(Vibrato)外,还可以用来模拟自然界的声音。严格来说,音色并非由波的波形来决定,而是由波的频谱包络曲线来决定的。在古典音色理论(Classical Theory of Timbre)中,会利用傅利叶转换,将波形转成频率-强度的频谱,此时绘制出来的图形曲线,就是频谱的包络曲线。然而,在实际上,在不同时间下所产生的包络曲线并不相同,因此在现代音色理论(Modern Theory of Timbre)中,将时间轴加入频谱的分析中,形成频率-强度-时间的三维图形。在使用电脑模拟声音的时候,只要能够模拟出同样的频谱出来,就可以模拟出相同的声音。

自然界的声音,大多可以使用 FM 来合成。而且 FM 在实作上相对简单,只要有四个振荡器就能够实作了。以下是 FM 的流程图:

频率调制(FM)合成的流程图

可以调整的参数有以下几种:

  • Amp:Amplitude,声音强度。
  • DUR:Duration,声音持续时间。
  • Fc:Carrier Frequency,载波频率。
  • Fm:Modulation Frequency,调制频率。
  • Imax:频带最大宽度。
  • F1:振幅使用的波表。
  • F2:调制频率使用的波表。

除了 Amp 外,其他的参数都会影响到 FM 模拟出来的声音音色。以下举几个声音模拟例子:

钟声(Bell)

当当当的钟声,特色在于声音在敲响后,会拉出很长的尾音。因此 DUR 长度通常为 5~15 秒,Fc 和 Fm 的比例为 5:7(200:280),Imax 为 10。

F1 和 F2 的波表相同,波形如下图:

钟声的 F1 与 F2 波表

钟声试听

木鼓声(Wood Drum)

咚咚咚的木鼓声,特色在于声音在打响后,一开始的频率并不稳定,而且声音强度很大,在很短的时间内声音强度降到很小,频率也很稳定。因此 DUR 长度通常为 0.2 秒,Fc 和 Fm 的比例为 16:11(80:55),Imax 为 25。

F1 的波表如下:

木鼓声的 F1 波表

F2 的波表如下:

木鼓声的 F2 波表

木鼓声试听

铜管声(Brass)

铜管乐器都有个共同的特性,那就是在一开始吹奏的时候需要使用比较大的力道,因此声音在一开始的强度会很高,接着趋于稳定,然后渐渐收尾。铜管的 DUR 长度常用值为 0.6 秒,Fc 和 Fm 的比例为 1:1(440:440),Imax 为 5。

F1 和 F2 的波表相同,波形如下图:

铜管声的 F1 与 F2 波表

铜管声试听

单簧管(竖笛)声(Clarinet)

簧管乐器借由空气振动簧片,振动强度十分稳定,频率变化会愈来愈小。单簧管的 DUR 长度的常用值为 0.5 秒,Fc 和 Fm 的比例为 3:2(900:600),Imax 为 4。

F1 的波表如下:

单簧管声的 F1 波表

F2 的波表如下:

单簧管声的 F2 波表

单簧管声试听

Csound FM 实作

<CsoundSynthesizer>
	<CsOptions>
	</CsOptions>
	
	<CsInstruments>
		sr = 44100   ;sample rate
		ksmps = 1    ;samples in a control period
		nchnls = 1   ;number of channels
		0dbfs = 100  ;value of 0db
		
		gisine ftgen 100, 0, 16384, 10, 1
		giexp10 ftgen 101, 0, 16384, 5, 1, 16384, 0.01
		giexpdrum ftgen 102, 0, 16384, 5, .7, 511, .8, 1533, 1, 2044, .8, 4088, .2, 8208, .01
		gilsegs ftgen 103, 0, 16384, 7, 0, 383, 1, 1660, 0, 14341, 0
		gilsegadsr ftgen 104, 0, 16384, 7, 0, 512, 1, 512, 0.75, 14848, 0.75, 512, 0
		giexpev ftgen 105, 0, 16384, 5, 0.01, 512, 1, 15360, 1, 512, 0.01
		giexp105 ftgen 106, 0, 16384, 5, 1, 8192, 0.5, 8192, 0.5
		
		instr 31
			;BELL
			isrt init p2
			idur init p3 ;5
			ipitch init p4
			
			imax init 10
			if1 init giexp10
			if2 init giexp10
			ifratio init 5./7.
			iamp init 50
			ilf init 280
			
			ifp = ilf*cpspch(p4)/cpspch(8.00)
			ifc = ifp
			ifm = ifp/ifratio
			
			a1 oscil iamp, 1./idur, if1
			a2 oscil ifm*imax, 1./idur, if2
			am oscil a2, ifm, gisine
			ac oscil a1, ifc+am, gisine
			out ac
		endin
		
		instr 32
			;WOOD DRUM
			isrt init p2
			idur init p3 ;0.2
			ipitch init p4
			
			imax init 25
			if1 init giexpdrum
			if2 init gilsegs
			ifratio init 16./11.
			iamp init 50
			ilf init 80
			
			ifp = ilf*cpspch(p4)/cpspch(8.00)
			ifc = ifp
			ifm = ifp/ifratio
			
			a1 oscil iamp, 1./idur, if1
			a2 oscil ifm*imax, 1./idur, if2
			am oscil a2, ifm, gisine
			ac oscil a1, ifc+am, gisine
			out ac
		endin
		
		instr 33
			;BRESS
			isrt init p2
			idur init p3 ;0.6
			ipitch init p4
			
			imax init 5
			if1 init gilsegadsr
			if2 init gilsegadsr
			ifratio init 1./1.
			iamp init 50
			ilf init 440
			
			ifp = ilf*cpspch(p4)/cpspch(8.00)
			ifc = ifp
			ifm = ifp/ifratio
			
			a1 oscil iamp, 1./idur, if1
			a2 oscil ifm*imax, 1./idur, if2
			am oscil a2, ifm, gisine
			ac oscil a1, ifc+am, gisine
			out ac
		endin
		
		instr 34
			;CLARINET
			isrt init p2
			idur init p3 ;0.5
			ipitch init p4
			
			imax init 4
			if1 init giexpev
			if2 init giexp105
			ifratio init 3./2.
			iamp init 50
			ilf init 900
			
			ifp = ilf*cpspch(p4)/cpspch(8.00)
			ifc = ifp
			ifm = ifp/ifratio
			
			a1 oscil iamp, 1./idur, if1
			a2 oscil ifm*imax, 1./idur, if2
			am oscil a2, ifm, gisine
			ac oscil a1, ifc+am, gisine
			out ac
		endin		
	</CsInstruments>
	<CsScore>
		t 0 60
		
		;ins	strt	dur	pitch
		i33	0.1	0.6	8.00
		i.	+	0.6	8.04
		i.	+	0.6	8.07
		i.	+	0.6	8.04
		i.	+	0.6	8.00
		
		i34	3.1	0.5	8.00
		i.	+	0.5	8.04
		i.	+	0.5	8.07
		i.	+	0.5	8.04
		i.	+	0.5	8.00
		
		i32	5.6	0.2	8.00
		i.	+	0.2	8.04
		i.	+	0.2	8.07
		i.	+	0.2	8.04
		i. + 0.2 8.00
		
		i31	6.6	5	8.00
		e
	</CsScore>
</CsoundSynthesizer>

高级 FM

使用愈多个 Carrier Oscillator(载波振荡器)或是 Modulation Oscillator(调制振荡器),可以合成出更复杂、更真实的自然声音。这部份将在以后介绍。